import ExploreTab;
import com.vitesselearning.coursedesign.engine.pagetype.Pagetype;
import com.vitesselearning.coursedesign.ui.AudioManager;
import com.vitesselearning.coursedesign.utilities.*;
import com.vitesselearning.coursedesign.debug.*;
/**
* @author Apolo Pena
* @author
* @version	1.0.1
* @description	Learner explores pieces of text  in a table by clicking to view tabbed content
* */
class ExploreTableTab extends ExploreTab {
	// The frame label for the selected template.
	public var templateType:String;
	// style name that dictates a clickable cell in a table
	private var clickableItemStyle:String = "tableCellExplore";
	// used to detect when all items have been clicked
	private var indexArray:Array;
	// flag to make sure last OSD is only displayed once
	private var isLastOsdDisplayed:Boolean = false;
	
	/**
	*  Constructor envokes it's parent constructor
	* 
	*/
	public function ExploreTableTab(timeline:MovieClip) {
		super(timeline);
	}
	
	/**
	 * Determine which layout style should be displayed.
	 *
	 */
	public function setTemplateType():Void {
		templateType = String(pageData.page[0].frameLabel[0]);
		course.userInterface.enableNav();
		timeline.gotoAndPlay(templateType);
	}
	
	/**
	*  updates the itemIndex
	*  @param evt an event object
	*/
	public function onRelease(evt:Object):Void {
		// the parent class requires that you manage the itemIndex value or it will always be zero, also this must be set
		itemIndex = evt.exploreIndex;
		indexArray[itemIndex].isClicked = true;
		// show the second OSD when appropriate, but never refresh the OSD again
		if (isAllCellsClicked() && !isLastOsdDisplayed) {
			isLastOsdDisplayed = true;
			showOSD(GlobalText.getGlobalOsd("click_next"));
		}
		updateTabs(itemIndex);
		timeline.contentWindow_mc.selectTabIndex(0);
	}
	/**
	*  determines if all the cells in a table have been clicked, you must set indexArray[itemIndex].isClicked = true whenever a cell is clicked for this method to work correctly
	*
	*/
	private function isAllCellsClicked():Boolean {
		var len:Number = indexArray.length;
		for (var i = 0; i<len; i++) {
			if (!indexArray[i].isClicked || indexArray[i].isClicked == undefined) {
				return false;
			}
		}
		return true;
	}
	/**
	*  initializes the activity
	*
	*/
	private function initActivity(settings:Object):Void {
		super.initActivity(settings);
		// set the layout out the page 
		var contentHeight:Number = contentWindow_mc.contentWidth;
		timeline.divider_mc._alpha = 100;
		timeline.contentHeader_mc._alpha = 100;
		
		// populate and listen.... shhh!
		timeline.table_tc.addEventListener("onRelease", this);
		timeline.pageText1_ta.setTextNode(pageData.page[0].pageContent[0].pageText[0]);
		timeline.pageText1_ta.show();
		timeline.tableTitleMc.subHeader_ta.setTextNode(pageData.page[0].media[0].tableTitle[0], styleSubHeader);
		timeline.tableTitleMc.subHeader_ta.show();
		timeline.tableTitleMc.gotoAndPlay("refresh");
		timeline.table_tc.autoSize = false;
		timeline.table_tc.setTableNode(pageData.page[0].media[0].table[0].table[0]);
		var clickableItemTotal:Number = getClickableItemTotal();
		indexArray = new Array();
		for (var i = 0; i<clickableItemTotal; i++) {
			indexArray.push({isClicked:false});
		}
		completePage();
		// handle autoSelet funtionality
		if (autoSelect) {
			timeline.table_tc.selectFirstItem();
		}
		showOSD(GlobalText.getGlobalOsd("click_item"));
	}
	/**
	* returns a number representing the total number of clickable cell in the VLtable
	*/
	private function getClickableItemTotal():Number {
		var tableData:Array = pageData.page[0].media[0].table[0].table[0];
		var total:Number = 0;
		var rowTotal:Number = tableData.tr.length;
		for (var r = 0; r<rowTotal; r++) {
			var colTotal = tableData.tr[r].td.length;
			var cells = new Array();
			for (var c = 0; c<colTotal; c++) {
				var txt = tableData.tr[r].td[c].text;
				var cellStyle = tableData.tr[r].td[c].style[0];
				if (cellStyle == clickableItemStyle) {
					total++;
				}
			}
		}
		return total;
	}
	/**
	* initializes settings from the timeline of the pagetype .fla
	*/
	private function initSettings(settings:Object) {
		for (var s in settings) {
			if (this[s] != undefined) {
				this[s] = settings[s];
			}
		}
	}
}